Gecko [ tsuru-no-tsurugi.tokyo ]

Name	Size	Permission	Date
peg	[ DIR ]	drwxr-xr-x	2025-03-06 19:41
and-let-star.scm	2.53 KB	-rw-r--r--	2021-05-10 17:28
arrays.scm	2.63 KB	-rw-r--r--	2021-05-10 17:28
atomic.scm	1.55 KB	-rw-r--r--	2021-05-10 17:28
binary-ports.scm	2.71 KB	-rw-r--r--	2021-05-10 17:28
boot-9.scm	166.42 KB	-rw-r--r--	2021-05-10 17:28
buffered-input.scm	4.82 KB	-rw-r--r--	2021-05-10 17:28
calling.scm	10.54 KB	-rw-r--r--	2021-05-10 17:28
command-line.scm	18.6 KB	-rw-r--r--	2021-05-10 17:28
common-list.scm	8.95 KB	-rw-r--r--	2021-05-10 17:28
control.scm	4.08 KB	-rw-r--r--	2021-05-10 17:28
copy-tree.scm	3.05 KB	-rw-r--r--	2021-05-10 17:28
curried-definitions.scm	1.79 KB	-rw-r--r--	2021-05-10 17:28
deprecated.scm	1.54 KB	-rw-r--r--	2021-05-10 17:28
documentation.scm	7.41 KB	-rw-r--r--	2021-08-27 06:21
eval-string.scm	2.99 KB	-rw-r--r--	2021-05-10 17:28
eval.scm	25.08 KB	-rw-r--r--	2021-05-10 17:28
exceptions.scm	14.38 KB	-rw-r--r--	2021-05-10 17:28
expect.scm	5.5 KB	-rw-r--r--	2021-05-10 17:28
fdes-finalizers.scm	1.06 KB	-rw-r--r--	2021-05-10 17:28
format.scm	65.47 KB	-rw-r--r--	2021-05-10 17:28
ftw.scm	25.06 KB	-rw-r--r--	2021-05-10 17:28
futures.scm	10.49 KB	-rw-r--r--	2021-05-10 17:28
gap-buffer.scm	9.59 KB	-rw-r--r--	2021-05-10 17:28
getopt-long.scm	16.49 KB	-rw-r--r--	2021-05-10 17:28
hash-table.scm	1.77 KB	-rw-r--r--	2021-05-10 17:28
hcons.scm	2.55 KB	-rw-r--r--	2021-05-10 17:28
history.scm	2.29 KB	-rw-r--r--	2021-05-10 17:28
i18n.scm	20.51 KB	-rw-r--r--	2021-05-10 17:28
iconv.scm	3.19 KB	-rw-r--r--	2021-05-10 17:28
lineio.scm	3.85 KB	-rw-r--r--	2021-05-10 17:28
list.scm	1.29 KB	-rw-r--r--	2021-05-10 17:28
local-eval.scm	9.84 KB	-rw-r--r--	2021-05-10 17:28
ls.scm	3.2 KB	-rw-r--r--	2021-05-10 17:28
match.scm	2.18 KB	-rw-r--r--	2021-05-10 17:28
match.upstream.scm	35.93 KB	-rw-r--r--	2021-05-10 17:28
networking.scm	3.33 KB	-rw-r--r--	2021-05-10 17:28
null.scm	1.21 KB	-rw-r--r--	2021-05-10 17:28
occam-channel.scm	7.26 KB	-rw-r--r--	2021-05-10 17:28
optargs.scm	15.75 KB	-rw-r--r--	2021-05-10 17:28
peg.scm	1.64 KB	-rw-r--r--	2021-05-10 17:28
poe.scm	3.3 KB	-rw-r--r--	2021-05-10 17:28
poll.scm	5.79 KB	-rw-r--r--	2021-05-10 17:28
popen.scm	9.27 KB	-rw-r--r--	2021-05-10 17:28
ports.scm	19.08 KB	-rw-r--r--	2021-05-10 17:28
posix.scm	2.73 KB	-rw-r--r--	2021-05-10 17:28
pretty-print.scm	16.88 KB	-rw-r--r--	2021-05-10 17:28
psyntax-pp.scm	182.88 KB	-rw-r--r--	2021-05-10 17:28
psyntax.scm	148.97 KB	-rw-r--r--	2021-08-27 06:21
q.scm	4.2 KB	-rw-r--r--	2021-05-10 17:28
quasisyntax.scm	5.22 KB	-rw-r--r--	2021-05-10 17:28
r5rs.scm	1.56 KB	-rw-r--r--	2021-05-10 17:28
r6rs-libraries.scm	10.38 KB	-rw-r--r--	2021-05-10 17:28
r7rs-libraries.scm	4.28 KB	-rw-r--r--	2021-05-10 17:28
rdelim.scm	7.72 KB	-rw-r--r--	2021-05-10 17:28
read.scm	32.52 KB	-rw-r--r--	2021-05-10 17:28
readline.scm	9.56 KB	-rw-r--r--	2021-05-10 17:28
receive.scm	1.06 KB	-rw-r--r--	2021-05-10 17:28
regex.scm	8.87 KB	-rw-r--r--	2021-05-10 17:28
runq.scm	8.18 KB	-rw-r--r--	2021-05-10 17:28
rw.scm	1.02 KB	-rw-r--r--	2021-05-10 17:28
safe-r5rs.scm	7.5 KB	-rw-r--r--	2021-05-10 17:28
safe.scm	1.25 KB	-rw-r--r--	2021-05-10 17:28
sandbox.scm	34.24 KB	-rw-r--r--	2021-05-10 17:28
save-stack.scm	2.15 KB	-rw-r--r--	2021-05-10 17:28
scm-style-repl.scm	11.62 KB	-rw-r--r--	2021-05-10 17:28
serialize.scm	3.78 KB	-rw-r--r--	2021-05-10 17:28
session.scm	17.72 KB	-rw-r--r--	2021-05-10 17:28
slib.scm	1.55 KB	-rw-r--r--	2021-05-10 17:28
stack-catch.scm	1.94 KB	-rw-r--r--	2021-05-10 17:28
streams.scm	5.86 KB	-rw-r--r--	2021-05-10 17:28
string-fun.scm	9.68 KB	-rw-r--r--	2021-05-10 17:28
suspendable-ports.scm	29.86 KB	-rw-r--r--	2021-05-10 17:28
textual-ports.scm	2.29 KB	-rw-r--r--	2021-05-10 17:28
threads.scm	12.54 KB	-rw-r--r--	2021-05-10 17:28
time.scm	2.07 KB	-rw-r--r--	2021-05-10 17:28
top-repl.scm	2.63 KB	-rw-r--r--	2021-05-10 17:28
unicode.scm	1005 B	-rw-r--r--	2021-05-10 17:28
vlist.scm	21.56 KB	-rw-r--r--	2021-05-10 17:28
weak-vector.scm	1.2 KB	-rw-r--r--	2021-05-10 17:28

Rename

;;;; streams.scm --- general lazy streams
;;;; -*- Scheme -*-

;;;; Copyright (C) 1999, 2001, 2004, 2006, 2015 Free Software Foundation, Inc.
;;;; 
;;;; This library is free software; you can redistribute it and/or
;;;; modify it under the terms of the GNU Lesser General Public
;;;; License as published by the Free Software Foundation; either
;;;; version 3 of the License, or (at your option) any later version.
;;;; 
;;;; This library is distributed in the hope that it will be useful,
;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;;; Lesser General Public License for more details.
;;;; 
;;;; You should have received a copy of the GNU Lesser General Public
;;;; License along with this library; if not, write to the Free Software
;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA

;; the basic stream operations are inspired by
;; (i.e. ripped off) Scheme48's `stream' package,
;; modulo stream-empty? -> stream-null? renaming.

(define-module (ice-9 streams)
  #:use-module ((srfi srfi-41) #:prefix srfi-41:)
  #:export (make-stream
            vector->stream port->stream
            stream->reversed-list
            stream->list&length stream->reversed-list&length
            stream->vector
            stream-fold)
  #:re-export ((srfi-41:stream-car . stream-car)
               (srfi-41:stream-cdr . stream-cdr)
               (srfi-41:stream-null? . stream-null?)
               (srfi-41:list->stream . list->stream)
               (srfi-41:stream->list . stream->list)
               (srfi-41:stream-for-each . stream-for-each)
               (srfi-41:stream-map . stream-map)))

;; Use:
;;
;; (make-stream producer initial-state)
;;  - PRODUCER is a function of one argument, the current state.
;;    it should return either a pair or an atom (i.e. anything that
;;    is not a pair).  if PRODUCER returns a pair, then the car of the pair
;;    is the stream's head value, and the cdr is the state to be fed
;;    to PRODUCER later.  if PRODUCER returns an atom, then the stream is
;;    considered depleted.
;;
;; (stream-car stream)
;; (stream-cdr stream)
;; (stream-null? stream)
;;  - yes.
;;
;; (list->stream list)
;; (vector->stream vector)
;;  - make a stream with the same contents as LIST/VECTOR.
;;
;; (port->stream port read)
;;  - makes a stream of values which are obtained by READing from PORT.
;;
;; (stream->list stream)
;;  - returns a list with the same contents as STREAM.
;;
;; (stream->reversed-list stream)
;;  - as above, except the contents are in reversed order.
;;
;; (stream->list&length stream)
;; (stream->reversed-list&length stream)
;;  - multiple-valued versions of the above two, the second value is the
;;    length of the resulting list (so you get it for free).
;;
;; (stream->vector stream)
;;  - yes.
;;
;; (stream-fold proc init stream0 ...)
;;  - PROC must take (+ 1 <number-of-stream-arguments>) arguments, like this:
;;    (PROC car0 ... init).  *NOTE*: the INIT argument is last, not first.
;;    I don't have any preference either way, but it's consistent with
;;    `fold[lr]' procedures from SRFI-1.  PROC is applied to successive
;;    elements of the given STREAM(s) and to the value of the previous
;;    invocation (INIT on the first invocation).  the last result from PROC
;;    is returned.
;;
;; (stream-for-each proc stream0 ...)
;;  - like `for-each' we all know and love.
;;
;; (stream-map proc stream0 ...)
;;  - like `map', except returns a stream of results, and not a list.

;; Code:

(define (make-stream m state)
  (srfi-41:stream-let recur ((state state))
    (let ((state (m state)))
      (if (pair? state)
          (srfi-41:stream-cons (car state) (recur (cdr state)))
          srfi-41:stream-null))))

(define (vector->stream v)
  (make-stream
   (let ((len (vector-length v)))
     (lambda (i)
       (or (= i len)
           (cons (vector-ref v i) (+ 1 i)))))
   0))

(define (stream->reversed-list&length stream)
  (let loop ((s stream) (acc '()) (len 0))
    (if (srfi-41:stream-null? s)
        (values acc len)
        (loop (srfi-41:stream-cdr s)
          (cons (srfi-41:stream-car s) acc) (+ 1 len)))))

(define (stream->reversed-list stream)
  (call-with-values
   (lambda () (stream->reversed-list&length stream))
   (lambda (l len) l)))

(define (stream->list&length stream)
  (call-with-values
   (lambda () (stream->reversed-list&length stream))
   (lambda (l len) (values (reverse! l) len))))

(define (stream->vector stream)
  (call-with-values
   (lambda () (stream->reversed-list&length stream))
   (lambda (l len)
     (let ((v (make-vector len)))
       (let loop ((i 0) (l l))
         (if (not (null? l))
             (begin
               (vector-set! v (- len i 1) (car l))
               (loop (+ 1 i) (cdr l)))))
       v))))

(define (stream-fold f init stream . rest)
  (if (null? rest) ;fast path
      (stream-fold-one f init stream)
      (stream-fold-many f init (cons stream rest))))

(define (stream-fold-one f r stream)
  (if (srfi-41:stream-null? stream)
      r
      (stream-fold-one f
                       (f (srfi-41:stream-car stream) r)
                       (srfi-41:stream-cdr stream))))

(define (stream-fold-many f r streams)
  (if (or-map srfi-41:stream-null? streams)
      r
      (stream-fold-many f
                        (apply f (let recur ((cars
                                              (map srfi-41:stream-car streams)))
                                   (if (null? cars)
                                       (list r)
                                       (cons (car cars)
                                             (recur (cdr cars))))))
                        (map srfi-41:stream-cdr streams))))

(define (port->stream port read)
  (make-stream (lambda (p)
                 (let ((o (read p)))
                   (or (eof-object? o)
                       (cons o p))))
               port))

;;; streams.scm ends here